• Willkommen im Geoclub - dem größten deutschsprachigen Geocaching-Forum. Registriere dich kostenlos, um alle Inhalte zu sehen und neue Beiträge zu erstellen.

Unterwegpunkt als Koorigierte Koordinate

EBSSgeo

Geocacher
Ich nochmal mit einem anderen Thema.

Habe einen Unterwegpunkt angelegt (Referenzpunkt)
Nun würde ich gern diesen Punkt automatisch als Korrigierte Koordinate speichern lassen.

Geht dies mit Bordmitteln? Oder benötigt man da wieder ein Makro? Oder ist es gar nicht möglich?

Besten Dank
 
OP
E

EBSSgeo

Geocacher
Danke dir, soweit funktioniert es auch.
Allerdings wenn der Wegpunkt als Referenzpunkt gesetzt ist geht es nicht.
Gibt es da noch die Möglichkeit das alles automatisch ändern zu lassen?
Mit Global Replace ging es nicht.

Gruss
 

8812

Geoguru
Wenn Du den Referenzpunkt anlegst, dann mußt Du ja mindestens die Koords manuell in das Koordinatenfeld pasten oder eintragen. Warum setzt Du nicht gleich stattdessen die Corrected Coords? Das ersparte dir die nachtägliche Umwandlung.

Hans
 
OP
E

EBSSgeo

Geocacher
Die Referenzpunkte hatte ich damals angelegt als ich das mit den Corrected Coords nicht wusste.
Jetzt möchte ich es aber gleich haben und daher würde ich das gern umwandeln.

Die neuen trage ich gleich richtig ein.
 

8812

Geoguru
Warum schreibst Du dann: "Habe einen Unterwegpunkt angelegt (Referenzpunkt)" und nicht "Ich habe vor einiger Zeit mehrere Unterwegpunkte angelegt(Referenzpunkt)".
Dein Ausgangsposting fürhrt völlig in die Irre. Da braucht man dann wieder X Posting um zum eigentlichen Wunsch zu kommen. Na gut, jetzt ist es endlich raus. Ein Makro wurde dir ja genannt. Es ändert Final Waypoints ab. Warum öffnest Du nicht einfach das Makro, schaust an welcher Stelle "Final" vorkommt und änderst es dann in Reference Points um?
 

8812

Geoguru
Also so:

Code:
#*******************************************
# MacVersion = 0.3
# MacDescription = User ReferencPoint to CC
# MacAuthor = HHL | Based on code by KaiTeam
# MacFileName = UserReferencePoint2CC.gsk
# MacUrl =
#*******************************************

$ByUserReferenceChild=TRUE
MACSETTINGS Type=R FileCheck=N
WHILE TRUE
    $FormExit = form($Form1,"")
    BEGINCASE
        CASE $FormExit = "SystemExit"
        RETURN Msg="Macro Canceled"

        CASE $FormExit = "OK"
        MACSETTINGS Type=S Vars=ByUserReferenceChild,ReferenceChildinFilter
        GOSUB Name=Run
        BREAK

        CASE $FormExit = "Cancel"
        RETURN Msg="Macro Canceled"
    ENDCASE
ENDWHILE

BEGINSUB Name=Run
	IF $ReferenceChildinFilter
		IF Not($_FilterActive)
			RETURN Msg=No filter set. You must set a filter to use the 'current filter' option. Macro canceled.
		ENDIF
        $_sql="Select cParent,cLat,cLon from WayAll WHERE cType='Reference Point' AND cParent IN(Select Code from Caches WHERE RowID IN(Select * From GridTemp))"
        $Data=Sqlite("sql",$_sql)
    ELSE
	    $_sql="Select cParent,cLat,cLon from WayAll WHERE cByUser=1 AND cType='Reference Point' AND cParent IN(Select Code from Caches WHERE RowID IN(Select * From GridTemp))"
        $Data=Sqlite("sql",$_sql)
    ENDIF

    $Data=Replace($_CrLf,";",$Data)

    $x=1
    $Count=RegExCount(";",$Data)
    TRANSACTION Action=Begin
    WHILE $x<$Count
        $Code=Extract($Data,";",$x)
        $Lat=Extract($Data,";",$x+1)
        $Lon=Extract($Data,";",$x+2)
    	IF Seek($Code)
    		SHOWSTATUS msg="Adding corrected coordites to $d_Code" Width=350
    		IF $d_HasCorrected=FALSE
        		TABLE Active=Corrected Scope=Parent
        		ADDNEW
        		$d_kAfterLat=$Lat
        		$d_kAfterLon=$Lon
        	ELSE
        		TABLE Active=Corrected Scope=Parent
        		$d_kAfterLat=$Lat
        		$d_kAfterLon=$Lon
        	ENDIF
    		TABLE Active=Caches
    	ENDIF
    	$x=$x+3
    ENDWHILE
    TRANSACTION Action=End
ENDSUB

<Data> VarName=$form1
#********************************************************************
# Form generated by GSAK form designer on Thu 15-Dec-2016 11:19:11
#********************************************************************

Name = Form1
  Type = Form
  Caption =  Reference child waypoints to corrected coordinates
  Height = 210
  Width = 402

Name = OK
  Type = Button
  Height = 25
  Left = 74
  Top = 120
  Width = 75
  Taborder = 8
  Caption = OK

Name = Cancel
  Type = Button
  Height = 25
  Left = 245
  Top = 120
  Width = 75
  Taborder = 9
  Caption = Cancel

Name = ByUserReferenceChild
  Type = Radiobutton
  Fontsize = 10
  Height = 20
  Left = 42
  Top = 36
  Width = 355
  Taborder = 12
  Caption = All "By user" reference child waypoints in the database or filter

Name = ReferenceChildinFilter
  Type = Radiobutton
  Fontsize = 10
  Height = 20
  Left = 42
  Top = 66
  Width = 331
  Taborder = 13
  Caption = All reference waypoints in the current filter

Name = Label1
  Type = Label
  Height = 17
  Left = 14
  Size = 10
  Top = 12
  Width = 321
  Caption = Select the waypoints to use for corrected coordinates

<enddata>

Viel Spaß
Hans
 
OP
E

EBSSgeo

Geocacher
Ok hätte ich vlt. besser schreiben können im Eingangspost. Werde demnächst drauf achten.
Kann dir nur wieder sagen wie dankbar ich dir für das umschreiben bin.
 
Oben